WeMos D1 mini: Jak dostat z NTP datum a čas

Dneska se podíváme jak si s Wemos d1 mini z internetu dostat datum a čas pro svůj projekt. Zvláštní, jak moc návodů ukazuje, jak přes NTP (Nework Time Protocol) získat čas, ale datum už ne.


Po důkladném kopání v hlubinách sítě jde zjistit, že NTP server umí poslat číslo počet vteřin od 1.1.1900. Unixový čas je počítán od 1.1.1970. Většinou je to označováno jako epoch, nebo epoch 0. Podle wikipedie v roce 2038 dojde k přetečení zásobníku pro 32bit číslo počítající vteřiny od začátku epoch. Tím údajně může vzniknout problém stejně jako tomu mělo dojít v roce 2000 neboli y2k.

Někteří y2k nepamatují, takže o půlnoci na přelomu tisíciletí se měly zhroutit počítačové sítě a operační systémy protože do té doby se prý s rokem pracovalo jako s dvouciferným číslem. Tedy po roce 99 by přišel rok 00. Potíž možná byla v tom, že 1.1.2000 byla sobota, ale 1.1.1900 bylo pondělí.
Podle mě to byla jen bublina aby se lidi báli další "katastrofy". Kdyby tohle nikdo "neošéfoval", tak by podle všeho měla přestat jít elektřina, doprava by zkolabovala a letadla by padaly z oblohy... Trochu přehnané, což?
Nic z toho se ale tehdy nestalo, buď to někdo opravdu dobře vyřešil a nebo to prostě byla jen fáma k postrašení lidí. Mimochodem v roce 1999 byla v americe zvýšená poptávka po domácích bunkrech a lidi brali obchody s potravinama útokem aby přežili katastrofu. Takže to byl i poměrně luxusní marketingový tah.

WeMos D1 mini

Potřebujeme:

Jakékoliv ESP8266, já mám WeMos D1 mini a wifi router přes který se pak připojíme k internetu. To je po hw stránce vše.
Knihovny NTPClient od gmag11 pro připojení k NTP serveru a knihovnu Time od PaulStoffregen na které tato knihovna závisí. Pro upload kódu je potřeba v menu Nástroje zvolit použitou desku ať je to Wemos d1, nebo cokoliv s ESP8266, nebo ESP32 co máme po ruce na otestování funkce.

Pár příkazů které potřebujeme znát:

NTP.getTimeDateString(); // formát řetězce je hh:mm:ss dd/MM/rrrr
NTP.isSummerTime(); // letní = 1, zimní = 0
NTP.getUptimeString(); // čas od spuštění esp/wemos
NTP.getFirstSync(); // datum a čas první synchronizace času s NTP

#include <TimeLib.h>
#include <NtpClientLib.h>
#include <ESP8266WiFi.h>

#define YOUR_WIFI_SSID "tvoje_wifi_SSID"
#define YOUR_WIFI_PASSWD "heslo_k_wifi"

int8_t timeZone = 1; // nacházíme se v časové zóně 1

// Start NTP až ESP získá svoji IP adresu
void onSTAGotIP(WiFiEventStationModeGotIP ipInfo) {
  Serial.printf("Got IP: %s\r\n", ipInfo.ip.toString().c_str());
  NTP.begin("pool.ntp.org", timeZone, true); // adresa NTP serveru
  NTP.setInterval(63); // sekundy za jak dlouho dojde k aktualizaci času z NTP
}

// Manage network disconnection
void onSTADisconnected(WiFiEventStationModeDisconnected event_info) {
  Serial.printf("Disconnected from SSID: %s\n", event_info.ssid.c_str());
  Serial.printf("Reason: %d\n", event_info.reason);
  //NTP.stop(); // NTP sync can be disabled to avoid sync errors
}

void processSyncEvent(NTPSyncEvent_t ntpEvent) {
  if (ntpEvent) {
    Serial.print("Time Sync error: ");
    if (ntpEvent == noResponse)
      Serial.println("NTP server not reachable");
    else if (ntpEvent == invalidAddress)
      Serial.println("Invalid NTP server address");
  }
  else {
    Serial.print("Got NTP time: ");
    Serial.println(NTP.getTimeDateString(NTP.getLastNTPSync()));
  }
}

boolean syncEventTriggered = false; // True if a time event has been triggered
NTPSyncEvent_t ntpEvent; // Last triggered event

void setup()
{
  static WiFiEventHandler e1, e2;

  Serial.begin(9600);
  Serial.println();
  WiFi.mode(WIFI_STA);
  WiFi.begin(YOUR_WIFI_SSID, YOUR_WIFI_PASSWD);

  NTP.onNTPSyncEvent([](NTPSyncEvent_t event) {
    ntpEvent = event;
    syncEventTriggered = true;
  });

  e1 = WiFi.onStationModeGotIP(onSTAGotIP);// As soon WiFi is connected, start NTP Client
  e2 = WiFi.onStationModeDisconnected(onSTADisconnected);
}

void loop(){
  Serial.print(NTP.getTimeDateString()); Serial.print(" ");
  Serial.print(NTP.isSummerTime() ? "Summer Time. " : "Winter Time. ");
  Serial.print("WiFi is ");
  Serial.print(WiFi.isConnected() ? "connected" : "not connected"); Serial.print(". ");
  Serial.print("Uptime: ");
  Serial.print(NTP.getUptimeString()); Serial.print(" since ");
  Serial.println(NTP.getTimeDateString(NTP.getFirstSync()).c_str());
  delay(2000);
}

Aby se mi s časem a datumem líp pracovalo, tak používám příkaz strtok k rozdělení řetězce na jednotlivé části času a datumu. Bohužel se mi nepodařilo zjistit, jak jednoduše rozdělit string, umím jen char array. Jestli kdokoliv zná lepší způsob, tak budu ráda za koment.
Kód můžeme vložit na konec smyčky loop před delay, nebo nahradit všechno co je v hlavní smyčce loop.

String TimeDateS = NTP.getTimeDateString(); //uložení času a data do string
   Serial.println(TimeDateS);
   char TimeDateCH[20];
   TimeDateS.toCharArray(TimeDateCH, 20); // převede string na char
   bool summertime = NTP.isSummerTime();

   if (strlen(TimeDateCH) > 1) {//rozdělení času a data
     byte Hodiny = atoi(strtok(TimeDateCH, "/ :"));
     byte Minuty = atoi(strtok(NULL, "/ :"));
     byte Sekundy = atoi(strtok(NULL, "/ :"));
     byte Den = atoi(strtok(NULL, "/ :"));
     byte Mesic = atoi(strtok(NULL, "/ :"));
     int Rok = atoi(strtok(NULL, "/ :"));
     Serial.println("Vlastni format casu a data"); 
     Serial.print(Hodiny); Serial.print(":");
     Serial.print(Minuty); Serial.print(":");
     Serial.print(Sekundy); Serial.print(" ");
     Serial.print(Den); Serial.print(".");
     Serial.print(Mesic); Serial.print(".");
     Serial.print(Rok); Serial.print(" ");
     Serial.println(summertime ? "Letni cas. " : "Zimni cas. ");
   } 

Tak to bude pro dnešek všechno. Ještě sketche ke stažení. Ten druhý sketch obsahuje i rozdělení času a data na jednotlivé části. Plus přikládám odkaz na svůj e-shop, kde si můžete ESP moduly zakoupit.